FYSBOOT     db     0ebh,03ch,090h

            db      'FYFYFYFY'
FYSBPB      db      25 dup (0)
            db      00                  ;Drive number, if a hard disk
            db      00                  ;Reserved
            db      29h                 ;Extended boot signature
            dd      06221972            ;Volume serial number
            db      'formatted 1'       ;Volume label
            db      'fat12   '          ;File type

FYSBCODE:   mov     ax,7C0h             ;Standard loading place for
            mov     ds,ax               ;   boot sector
            mov     es,ax

            mov     ah,0fh              ;Get current display mode
            int     10h                 ;Bios services

            mov     si,offset FYSBOOTMSG
FYSBMLC:    mov     al,[si]             ;Get next character
            or      al,al               ;End of string?
            jz      FYSBMD              ;Yes, so end
            mov     ah,0Eh              ;Write text in teletype mode
            int     10h                 ;Bios services
            inc     si
            jmp     short FYSBMLC

FYSBMD:     mov     ah,00h              ;Read keyboard character
            int     16h                 ;Bios services
            mov     al,13               ;Process a carriage return
            mov     ah,0eh
            int     10h
            mov     al,10               ;Process a line feed
            mov     ah,0eh
            int     10h
            int     19h                 ;Do a warm boot

FYSBOOTMSG  db      13,10,13,10
            db      '     This disk was formatted with a program from',13,10
            db      '        Forever Young Software, by Ben Lunt.',13,10
            db      13,10
            db      '     This is a non-system disk.  Remove this disk',13,10
            db      '        and press any key to reboot your system.',13,10
            db      13,10, 43 dup (' '), 0

            org     510
            db      55h                 ;Boot sector has to end with
            db      0AAh                ;   these bytes, in this order
